Oracle在plsql中创建表类型数据
表类型的操作在oracle中会稍微有些复杂,我们这里通过一个简单的例子,来给大家做个讲解。
前提条件:
create table qq_games(
qq number,
game varchar2(50)
);
insert into qq_games values(11111,'a-b-c');
insert into qq_games values(22222,'b-c');
要将这个表格的数据,查询成下面的格式:
11111 a
11111 b
11111 c
22222 b
22222 c
要拆分数据,并且以一个新表的结构来进行展示的话,需要有如下的步骤:
-- 在oracle里面,要自己先创建一个表类型,因为表类型有多个字段,所以不能直接创建的,需要先创建数据库最顶层的对象object
create or replace type 类型名字 is object (字段名字1 数据类型, 字段名字2 数据类型, ...);
create or replace type qq is object(qq number, game varchar2(50));
通过这个object创建一个表格的结构:
create or replace type 类型名字 is table of object类型的名字;
create or replace type qq_t is table of qq;
-- 通过函数,读取原表的数据,并且对数据进行计算,最后展示成一个目标表格的样式
create or replace function fun_qq
-- 定义函数返回的一个表格的类型
return qq_t
as
--初始化这个表格
t qq_t:=qq_t();
--定义一个变量来接收i.game的内容
s varchar2(50);
le number;
--定义表的行号,默认从1开始
c number:=1;
begin
--一行行的读取 qq_games 行数据,这里用的是游标
for i in (select * from qq_games) loop
--每一个i就是一行数据,里面有 i.qq i.game
--现在对i.game进行数据的拆分
s:=i.game;
--判断s里面有多少个分隔符
le:=length(s)-length(replace(s,'-',''));
--有几个分隔符就循环几次
for j in 1..le loop
--获取第一个分隔符前面的内容 例如 a-b-c 那么就是获取 a
--将数据放入表类型,需要将表序号往下挪一格
t.extend;
t(c):=qq(i.qq,substr(s,1,instr(s,'-')-1));
--写入了第一个分隔符之前的数据,将后面的数据重新截取
s:=substr(s,instr(s,'-')+1);
--写完数据让行号—+1
c:=c+1;
end loop;
--再额外的写入最后剩下的字符串
t.extend;
t(c):=qq(i.qq,s);
c:=c+1;
end loop;
-- 返回写入了数据的表类型变量 t
return t;
end;
-- 查看表类型函数执行的结果
select * from table(fun_qq);